dzming.li
A vibe coded tangled fork which supports pijul.
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in consle that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 docs = self.callPackage ./nix/pkgs/docs.nix {
102 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
103 inherit (pkgs) pagefind;
104 };
105 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
106 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
107 knot = self.callPackage ./nix/pkgs/knot.nix {};
108 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
109 did-method-plc = self.callPackage ./nix/pkgs/did-method-plc.nix {};
110 bluesky-jetstream = self.callPackage ./nix/pkgs/bluesky-jetstream.nix {};
111 bluesky-relay = self.callPackage ./nix/pkgs/bluesky-relay.nix {};
112 tap = self.callPackage ./nix/pkgs/tap.nix {};
113 });
114 in {
115 overlays.default = final: prev: {
116 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly did-method-plc bluesky-jetstream bluesky-relay tap;
117 };
118
119 packages = forAllSystems (system: let
120 pkgs = nixpkgsFor.${system};
121 packages = mkPackageSet pkgs;
122 staticPackages = mkPackageSet pkgs.pkgsStatic;
123 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
124 in {
125 inherit
126 (packages)
127 appview
128 appview-static-files
129 lexgen
130 goat
131 spindle
132 knot
133 knot-unwrapped
134 sqlite-lib
135 docs
136 dolly
137 did-method-plc
138 bluesky-jetstream
139 bluesky-relay
140 tap
141 ;
142
143 pkgsStatic-appview = staticPackages.appview;
144 pkgsStatic-knot = staticPackages.knot;
145 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
146 pkgsStatic-spindle = staticPackages.spindle;
147 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
148 pkgsStatic-dolly = staticPackages.dolly;
149
150 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
151 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
152 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
153 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
154 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
155
156 treefmt-wrapper = pkgs.treefmt.withConfig {
157 settings.formatter = {
158 alejandra = {
159 command = pkgs.lib.getExe pkgs.alejandra;
160 includes = ["*.nix"];
161 };
162
163 gofmt = {
164 command = pkgs.lib.getExe' pkgs.go "gofmt";
165 options = ["-w"];
166 includes = ["*.go"];
167 };
168
169 # prettier = let
170 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
171 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
172 # '';
173 # in {
174 # command = wrapper;
175 # options = ["-w"];
176 # includes = ["*.html"];
177 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
178 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
179 # };
180 };
181 };
182 });
183 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
184 devShells = forAllSystems (system: let
185 pkgs = nixpkgsFor.${system};
186 packages' = self.packages.${system};
187 staticShell = pkgs.mkShell.override {
188 stdenv = pkgs.pkgsStatic.stdenv;
189 };
190 in {
191 default = staticShell {
192 nativeBuildInputs = [
193 pkgs.go
194 pkgs.air
195 pkgs.gopls
196 pkgs.httpie
197 pkgs.litecli
198 pkgs.websocat
199 pkgs.tailwindcss
200 pkgs.nixos-shell
201 pkgs.redis
202 pkgs.worker-build
203 pkgs.cargo-generate
204 (fenix.packages.${system}.combine [
205 fenix.packages.${system}.stable.cargo
206 fenix.packages.${system}.stable.rustc
207 fenix.packages.${system}.stable.rust-src
208 fenix.packages.${system}.stable.clippy
209 fenix.packages.${system}.stable.rustfmt
210 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
211 ])
212 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
213 packages'.lexgen
214 packages'.treefmt-wrapper
215 ];
216 shellHook = ''
217 mkdir -p appview/pages/static
218 # temporary self-heal for workspaces that copied static assets as read-only
219 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
220 # no preserve is needed because watch-tailwind will want to be able to overwrite
221 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
222 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
223 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
224 '';
225 env.CGO_ENABLED = 1;
226 };
227 });
228 apps = forAllSystems (system: let
229 pkgs = nixpkgsFor."${system}";
230 packages' = self.packages.${system};
231 air-watcher = name: arg:
232 pkgs.writeShellScriptBin "run"
233 ''
234 export PATH=${pkgs.go}/bin:$PATH
235 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
236 -build.args_bin "${arg}"
237 '';
238 tailwind-watcher =
239 pkgs.writeShellScriptBin "run"
240 ''
241 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
242 '';
243 in {
244 fmt = {
245 type = "app";
246 program = pkgs.lib.getExe packages'.treefmt-wrapper;
247 };
248 watch-appview = {
249 type = "app";
250 program = toString (pkgs.writeShellScript "watch-appview" ''
251 echo "copying static files to appview/pages/static..."
252 mkdir -p appview/pages/static
253 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
254 ${air-watcher "appview" ""}/bin/run
255 '');
256 };
257 watch-knot = {
258 type = "app";
259 program = ''${air-watcher "knot" "server"}/bin/run'';
260 };
261 watch-spindle = {
262 type = "app";
263 program = ''${air-watcher "spindle" ""}/bin/run'';
264 };
265 watch-tailwind = {
266 type = "app";
267 program = ''${tailwind-watcher}/bin/run'';
268 };
269 serve-docs = {
270 type = "app";
271 program = toString (pkgs.writeShellScript "serve-docs" ''
272 echo "building docs..."
273 docsOut=$(nix build --no-link --print-out-paths .#docs)
274 echo "serving docs at http://localhost:1414"
275 cd "$docsOut"
276 exec ${pkgs.python3}/bin/python3 -m http.server 1414
277 '');
278 };
279 vm = let
280 guestSystem =
281 if pkgs.stdenv.hostPlatform.isAarch64
282 then "aarch64-linux"
283 else "x86_64-linux";
284 in {
285 type = "app";
286 program =
287 (pkgs.writeShellApplication {
288 name = "launch-vm";
289 text = ''
290 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
291 cd "$rootDir"
292
293 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
294
295 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
296 exec ${pkgs.lib.getExe
297 (import ./nix/vm.nix {
298 inherit nixpkgs self;
299 system = guestSystem;
300 hostSystem = system;
301 }).config.system.build.vm}
302 '';
303 })
304 + /bin/launch-vm;
305 };
306 gomod2nix = {
307 type = "app";
308 program = toString (pkgs.writeShellScript "gomod2nix" ''
309 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
310 '');
311 };
312 lexgen = {
313 type = "app";
314 program =
315 (pkgs.writeShellApplication {
316 name = "lexgen";
317 text = ''
318 if ! command -v lexgen > /dev/null; then
319 echo "error: must be executed from devshell"
320 exit 1
321 fi
322
323 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
324 cd "$rootDir"
325
326 rm -f api/tangled/*
327 lexgen --build-file lexicon-build-config.json lexicons
328 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
329 # lexgen generates incomplete Marshaler/Unmarshaler for union types
330 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
331 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
332 ${pkgs.gotools}/bin/goimports -w api/tangled/*
333 go run ./cmd/cborgen/
334 lexgen --build-file lexicon-build-config.json lexicons
335 rm api/tangled/*.bak
336 '';
337 })
338 + /bin/lexgen;
339 };
340 });
341
342 nixosModules.appview = {
343 lib,
344 pkgs,
345 ...
346 }: {
347 imports = [./nix/modules/appview.nix];
348
349 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
350 };
351 nixosModules.knot = {
352 lib,
353 pkgs,
354 ...
355 }: {
356 imports = [./nix/modules/knot.nix];
357
358 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
359 };
360 nixosModules.spindle = {
361 lib,
362 pkgs,
363 ...
364 }: {
365 imports = [./nix/modules/spindle.nix];
366
367 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
368 };
369 nixosModules.did-method-plc = {
370 lib,
371 pkgs,
372 ...
373 }: {
374 imports = [./nix/modules/did-method-plc.nix];
375 services.did-method-plc.package = lib.mkDefault self.packages.${pkgs.system}.did-method-plc;
376 };
377 nixosModules.bluesky-relay = {
378 lib,
379 pkgs,
380 ...
381 }: {
382 imports = [./nix/modules/bluesky-relay.nix];
383 services.bluesky-relay.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-relay;
384 };
385 nixosModules.bluesky-jetstream = {
386 lib,
387 pkgs,
388 ...
389 }: {
390 imports = [./nix/modules/bluesky-jetstream.nix];
391 services.bluesky-jetstream.package = lib.mkDefault self.packages.${pkgs.system}.bluesky-jetstream;
392 };
393 };
394}